16강애니메이션과 상태 머신

$Sprite.play("run")
$Sprite.play("idle")
$Sprite.flip_h = true      # 좌우 반전 (5강 참고)
$Sprite.stop()

func _physics_process(delta):
	if velocity.length() > 0:
		$Sprite.play("run")
	else:
		$Sprite.play("idle")

	if Input.is_action_just_pressed("attack"):
		$Sprite.play("attack")

	if hp <= 0:
		$Sprite.play("die")

extends CharacterBody2D

enum State { IDLE, RUN, JUMP, ATTACK, HURT, DEAD }

@export var speed := 300.0
@export var accel := 2200.0

var state: State = State.IDLE
var _state_time := 0.0

@onready var spr: AnimatedSprite2D = $Sprite

func _physics_process(delta: float) -> void:
	_state_time += delta
	match state:
		State.IDLE:   _idle(delta)
		State.RUN:    _run(delta)
		State.JUMP:   _jump(delta)
		State.ATTACK: _attack(delta)
		State.HURT:   _hurt(delta)
		State.DEAD:   _dead(delta)
	move_and_slide()

# ── 상태 전환은 이 함수 하나로만 한다 ─────
func change(next: State) -> void:
	if state == next:
		return
	if state == State.DEAD:
		return                      # 죽으면 못 나감
	state = next
	_state_time = 0.0
	match next:
		State.IDLE:   spr.play("idle")
		State.RUN:    spr.play("run")
		State.JUMP:   spr.play("jump")
		State.ATTACK: spr.play("attack")
		State.HURT:   spr.play("hurt")
		State.DEAD:   spr.play("die")

# ── 각 상태의 행동 ───────────────
func _idle(delta: float) -> void:
	velocity = velocity.move_toward(
		Vector2.ZERO, accel * delta)
	if Input.is_action_just_pressed("attack"):
		change(State.ATTACK)
	elif _input_dir() != Vector2.ZERO:
		change(State.RUN)

func _run(delta: float) -> void:
	var dir := _input_dir()
	velocity = velocity.move_toward(
		dir * speed, accel * delta)
	if dir.x != 0.0:
		spr.flip_h = dir.x < 0.0
	if Input.is_action_just_pressed("attack"):
		change(State.ATTACK)
	elif dir == Vector2.ZERO:
		change(State.IDLE)

func _attack(delta: float) -> void:
	# 공격 중엔 못 움직인다.
	velocity = velocity.move_toward(
		Vector2.ZERO, accel * 2.0 * delta)
	if _state_time >= 0.4:
		change(State.IDLE)

func _hurt(delta: float) -> void:
	velocity = velocity.move_toward(
		Vector2.ZERO, accel * 0.5 * delta)
	if _state_time >= 0.25:
		change(State.IDLE)

func _jump(_delta: float) -> void:
	pass

func _dead(_delta: float) -> void:
	velocity = Vector2.ZERO

func _input_dir() -> Vector2:
	return Input.get_vector(
		"move_left", "move_right", "move_up", "move_down")

# ── 외부에서 부르는 것 ─────────────
func take_damage(amount: int) -> void:
	if state == State.DEAD:
		return
	hp -= amount
	change(State.DEAD if hp <= 0 else State.HURT)

func _ready() -> void:
	spr.animation_finished.connect(_on_anim_finished)

func _on_anim_finished() -> void:
	match state:
		State.ATTACK, State.HURT:
			change(State.IDLE)