22강멀티플레이어의 기본 구조

   플레이어1 (호스트 = 서버 + 클라이언트)
      ↑↓        ↑↓
  플레이어2   플레이어3

        서버 (게임 로직만, 화면 없음)
     ↑↓    ↑↓    ↑↓
    P1    P2    P3

   P1 ←→ P2
    ↖   ↗
      P3

multiplayer.get_unique_id()      # 내 ID
# 서버는 항상 1
# 클라이언트는 2 이상의 랜덤한 값

multiplayer.is_server()          # 내가 서버인가
multiplayer.get_peers()  # 접속한 다른 ID 목록

# res://autoload/net.gd
extends Node

const PORT := 8910
const MAX_PLAYERS := 4

signal player_joined(id: int)
signal player_left(id: int)

var players: Dictionary = {}    # id -> {name, ...}

func _ready() -> void:
	multiplayer.peer_connected.connect(_on_peer_connected)
	multiplayer.peer_disconnected.connect(_on_peer_left)
	multiplayer.connected_to_server.connect(_on_connected)
	multiplayer.connection_failed.connect(_on_failed)
	multiplayer.server_disconnected.connect(_on_server_gone)

func host() -> bool:
	var peer := ENetMultiplayerPeer.new()
	var err := peer.create_server(PORT, MAX_PLAYERS)
	if err != OK:
		push_error("서버 생성 실패: %d" % err)
		return false
	multiplayer.multiplayer_peer = peer
	players[1] = {"name": "호스트"}
	print("서버 시작. 포트 ", PORT)
	return true

func join(address := "127.0.0.1") -> bool:
	var peer := ENetMultiplayerPeer.new()
	var err := peer.create_client(address, PORT)
	if err != OK:
		push_error("접속 실패: %d" % err)
		return false
	multiplayer.multiplayer_peer = peer
	print("접속 시도 → ", address)
	return true

func leave() -> void:
	if multiplayer.multiplayer_peer:
		multiplayer.multiplayer_peer.close()
	multiplayer.multiplayer_peer = null
	players.clear()

# ── 콜백 ────────────────────
func _on_peer_connected(id: int) -> void:
	print("접속함: ", id)
	players[id] = {"name": "플레이어 %d" % id}
	player_joined.emit(id)

func _on_peer_left(id: int) -> void:
	print("나감: ", id)
	players.erase(id)
	player_left.emit(id)

func _on_connected() -> void:
	print("서버에 연결됨. 내 ID = ",
		multiplayer.get_unique_id())

func _on_failed() -> void:
	push_error("서버에 연결하지 못했습니다")
	multiplayer.multiplayer_peer = null

func _on_server_gone() -> void:
	push_error("서버와의 연결이 끊겼습니다")
	multiplayer.multiplayer_peer = null
	get_tree().change_scene_to_file("res://scenes/title.tscn")

extends Control

func _ready() -> void:
	$VBox/HostBtn.pressed.connect(_on_host)
	$VBox/JoinBtn.pressed.connect(_on_join)
	Net.player_joined.connect(_refresh)
	Net.player_left.connect(_refresh)

func _on_host() -> void:
	if Net.host():
		get_tree().change_scene_to_file(
			"res://scenes/arena.tscn")

func _on_join() -> void:
	var addr: String = $VBox/AddressEdit.text
	if addr.is_empty():
		addr = "127.0.0.1"
	Net.join(addr)

func _refresh(_id := 0) -> void:
	$VBox/PlayerList.text = ""
	for id in Net.players:
		$VBox/PlayerList.text += "%d: %s\n" % [
			id, Net.players[id].name]

Arena              (Node2D)
├─ TileMapLayer
├─ Players         (Node2D)     ← 여기에 캐릭터들이 생김
└─ Spawner         (MultiplayerSpawner)

extends Node2D

const PLAYER := preload("res://scenes/player.tscn")

func _ready() -> void:
	if not multiplayer.is_server():
		return
	# 이미 접속해 있는 사람들
	_spawn(1)
	for id in multiplayer.get_peers():
		_spawn(id)
	# 나중에 들어오는 사람들
	multiplayer.peer_connected.connect(_spawn)
	multiplayer.peer_disconnected.connect(_despawn)

func _spawn(id: int) -> void:
	var p := PLAYER.instantiate()
	p.name = str(id)  # 이름 = ID (중요!)
	p.position = _spawn_point(id)
	$Players.add_child(p, true)

func _despawn(id: int) -> void:
	var p := $Players.get_node_or_null(str(id))
	if p:
		p.queue_free()

func _spawn_point(id: int) -> Vector2:
	var a := (id % 8) * TAU / 8.0
	return Vector2(400, 300) + Vector2.RIGHT.rotated(a) * 180.0

extends CharacterBody2D

func _ready() -> void:
	# 노드 이름이 곧 주인의 ID
	set_multiplayer_authority(name.to_int())

	# 내 캐릭터에만 카메라를 붙인다.
	if is_multiplayer_authority():
		$Camera2D.make_current()

func _physics_process(delta: float) -> void:
	if not is_multiplayer_authority():
		return  # 남의 캐릭터는 입력을 안 받음
	var dir := Input.get_vector(
		"move_left", "move_right", "move_up", "move_down")
	velocity = dir * 300.0
	move_and_slide()