4강delta — 프레임에 흔들리지 않는 시간

문제 상황부터 본다#

캐릭터를 오른쪽으로 움직이는 가장 순진한 코드입니다.

func _process(_delta: float) -> void:
	position.x += 5

"한 프레임에 5픽셀씩 간다"는 뜻입니다. 잘 돌아가는 것처럼 보입니다. 그런데 이 코드에는 심각한 문제가 있습니다.

같은 게임인데 기기마다 캐릭터 속도가 다릅니다. 좋은 컴퓨터에서는 캐릭터가 2배 빠르고, 프레임이 떨어지면 슬로우 모션이 걸립니다.

delta — "지난 프레임 이후 흐른 시간"#

Godot이 _process(delta) 로 넘겨주는 delta는 아주 단순한 값입니다.

여기에 초당 속도를 곱하면 "이번 프레임 동안 가야 할 거리" 가 나옵니다.

const SPEED := 300.0   # 초당 300픽셀

func _process(delta: float) -> void:
	position.x += SPEED * delta

프레임이 어떻게 흔들려도 1초에 가는 거리는 같습니다. 프레임이 떨어지면 뚝뚝 끊겨 보이지만 느려지지는 않습니다.

실습 — 나란히 놓고 비교하기#

말로 백 번 듣는 것보다 한 번 보는 게 낫습니다.

1) 씬 구성#

실습용 에셋 내려받기

빨강 상자 box_a.svg 96×96 내려받기 초록 상자 box_b.svg 96×96 내려받기

전부 CC0 다. 에셋 모음 전체 보기 · 한꺼번에 받기 (ZIP)

main.tscn에 Sprite2D를 두 개 놓고 이름을 Bad, Good으로 바꿉니다. Bad는 y=150, Good은 y=250 정도로 위아래로 떨어뜨려 놓으세요.

2) 스크립트#

main.tscn 루트에 붙입니다.

extends Node2D

const SPEED := 300.0

@onready var bad: Sprite2D = $Bad
@onready var good: Sprite2D = $Good

func _process(delta: float) -> void:
	bad.position.x += 5.0  # 프레임당 5픽셀
	good.position.x += SPEED * delta # 초당 300픽셀

	# 화면 밖으로 나가면 왼쪽 끝으로 되돌린다.
	if bad.position.x > 1000.0:
		bad.position.x = 0.0
	if good.position.x > 1000.0:
		good.position.x = 0.0

3) 프레임 제한을 걸고 관찰#

3강에서 만든 Load Level 부하 코드를 같이 켜거나, 아래 한 줄로 FPS를 직접 제한합니다.

func _ready() -> void:
	Engine.max_fps = 20   # 일부러 20 FPS로 묶는다

delta를 곱하면 안 되는 것들#

여기서 초보가 반대 방향으로 실수합니다. 모든 곳에 delta를 곱하는 것입니다.

velocity *= 0.9   # 매 프레임 10%씩 줄인다

# 초당 감속률 6.0. 프레임과 무관하게 같은 곡선.
velocity = velocity.lerp(Vector2.ZERO, 1.0 - exp(-6.0 * delta))

delta가 커지는 순간을 조심하기#

노트북 뚜껑을 닫았다 열거나, 브라우저 탭을 다른 곳으로 옮겼다가 돌아오면 delta가 갑자기 2초처럼 커질 수 있습니다. 그러면 이런 일이 벌어집니다.

• 캐릭터가 벽을 뚫고 순간이동한다
• 총알이 적을 그냥 통과한다

Godot은 이걸 막으려고 한 프레임에 처리할 물리 스텝 수를 제한합니다 (프로젝트 설정 → Physics → Common → Max Physics Steps Per Frame). 직접 만드는 로직에서도 필요하면 이렇게 막습니다.

func _process(delta: float) -> void:
	# 한 프레임에 0.1초 이상은 없던 일로 한다.
	var dt := minf(delta, 0.1)
	position.x += SPEED * dt

다음 강의 — 이제 "얼마나 움직이는가"는 해결됐습니다. 다음은 "어디로" 입니다. 좌표계, 원점, 피벗, 로컬과 글로벌을 다룹니다.