18강UI와 HUD

HUD                        (CanvasLayer)
└─ Root                    (Control)  Layout: Full Rect
    └─ Margin              (MarginContainer)  여백 16
        ├─ TopLeft         (VBoxContainer)  Layout: Top Left
        │   ├─ HpBar       (ProgressBar)  min size (200, 18)
        │   └─ HpLabel     (Label)
        └─ TopRight        (VBoxContainer)  Layout: Top Right
            ├─ ScoreLabel  (Label)
            └─ TimeLabel   (Label)

extends CanvasLayer

@onready var hp_bar: ProgressBar = $Root/Margin/TopLeft/HpBar
@onready var hp_label: Label = $Root/Margin/TopLeft/HpLabel
@onready var score_label: Label = $Root/Margin/TopRight/ScoreLabel

func _ready() -> void:
	var player := get_tree().get_first_node_in_group("player")
	if player:
		player.health_changed.connect(_on_health_changed)

func _on_health_changed(cur: int, max_v: int) -> void:
	hp_label.text = "%d / %d" % [cur, max_v]
	# 숫자는 즉시, 막대는 부드럽게 따라오게 (17강)
	var tw := create_tween()
	tw.set_ease(Tween.EASE_OUT)
	tw.set_trans(Tween.TRANS_CUBIC)
	tw.tween_property(hp_bar, "value",
		float(cur) / max_v * 100.0, 0.25)

func set_score(v: int) -> void:
	score_label.text = "점수 %d" % v

extends MarginContainer

func _ready() -> void:
	get_tree().root.size_changed.connect(_apply)
	_apply()

func _apply() -> void:
	var safe := DisplayServer.get_display_safe_area()
	var full := DisplayServer.window_get_size()
	# 화면 밖으로 밀린 만큼을 여백으로 준다.
	var l := maxi(safe.position.x, 16)
	var t := maxi(safe.position.y, 16)
	var r := maxi(full.x - safe.end.x, 16)
	var b := maxi(full.y - safe.end.y, 16)
	add_theme_constant_override("margin_left", l)
	add_theme_constant_override("margin_top", t)
	add_theme_constant_override("margin_right", r)
	add_theme_constant_override("margin_bottom", b)

PauseMenu             (CanvasLayer)  layer 10
└─ Root               (Control)  Full Rect
    ├─ Dim            (ColorRect)  Full Rect, 검정 알파 0.6
    └─ Center         (CenterContainer)  Full Rect
        └─ Panel      (PanelContainer)
            └─ VBox   (VBoxContainer)
                ├─ Title    (Label)  "일시정지"
                ├─ Resume   (Button) "계속하기"
                ├─ Restart  (Button) "다시 시작"
                └─ Quit     (Button) "나가기"

extends CanvasLayer

func _ready() -> void:
	# 게임이 멈춰도 이 메뉴는 계속 동작해야 한다.
	process_mode = Node.PROCESS_MODE_WHEN_PAUSED
	hide()
	$Root/Center/Panel/VBox/Resume.pressed.connect(close)
	$Root/Center/Panel/VBox/Restart.pressed.connect(_restart)
	$Root/Center/Panel/VBox/Quit.pressed.connect(_quit)

func _unhandled_input(e: InputEvent) -> void:
	if e.is_action_pressed("ui_cancel"):
		if get_tree().paused: close()
		else: open()
		get_viewport().set_input_as_handled()

func open() -> void:
	get_tree().paused = true
	show()
	# 게임패드/키보드로 바로 조작되게 포커스를 준다.
	$Root/Center/Panel/VBox/Resume.grab_focus()

func close() -> void:
	hide()
	get_tree().paused = false

func _restart() -> void:
	get_tree().paused = false
	get_tree().reload_current_scene()

func _quit() -> void:
	get_tree().quit()

# 개별 노드만 예외를 두고 싶을 때
label.add_theme_font_size_override("font_size", 28)
label.add_theme_color_override("font_color", Color.RED)