13강레이캐스트와 판정

Player          (CharacterBody2D)
├─ Sprite2D
├─ CollisionShape2D
└─ GroundCheck  (RayCast2D)   Target Position (0, 40)

extends CharacterBody2D

@onready var ground: RayCast2D = $GroundCheck

func _physics_process(_delta: float) -> void:
	if ground.is_colliding():
		var hit := ground.get_collider()
		var point := ground.get_collision_point()
		print("발밑: ", hit.name, " @ ", point)

func _shoot() -> void:
	var space := get_world_2d().direct_space_state
	var from := global_position
	var to := from + Vector2.RIGHT.rotated(rotation) * 800.0

	var q := PhysicsRayQueryParameters2D.create(from, to)
	q.exclude = [self]            # 나 자신은 무시
	q.collision_mask = 1 | 4  # world(1) + enemy(3번=4)
	q.collide_with_areas = false

	var hit := space.intersect_ray(q)
	if hit.is_empty():
		return

	print("맞음: ", hit.collider.name)
	print("위치: ", hit.position)
	print("법선: ", hit.normal)

extends CharacterBody2D

@export var speed := 140.0
@export var sight_range := 380.0
@export var sight_angle := 70.0  # 시야각(도), 좌우 합계

var _target: Node2D
var _can_see := false

func _ready() -> void:
	_target = get_tree().get_first_node_in_group("player")

func _physics_process(delta: float) -> void:
	_can_see = _check_sight()
	if _can_see:
		var dir := global_position.direction_to(
			_target.global_position)
		velocity = velocity.move_toward(
			dir * speed, 900.0 * delta)
	else:
		velocity = velocity.move_toward(
			Vector2.ZERO, 700.0 * delta)
	move_and_slide()

func _check_sight() -> bool:
	if _target == null or not is_instance_valid(_target):
		return false

	var to_target := _target.global_position - global_position

	# 1) 거리 검사 — 가장 싸므로 먼저
	if to_target.length() > sight_range:
		return false

	# 2) 각도 검사 — 그다음으로 싸다
	var facing := Vector2.RIGHT.rotated(rotation)
	var half := deg_to_rad(sight_angle) * 0.5
	if absf(facing.angle_to(to_target)) > half:
		return false

	# 3) 시선 차단 검사 — 가장 비싸므로 마지막
	var space := get_world_2d().direct_space_state
	var q := PhysicsRayQueryParameters2D.create(
		global_position, _target.global_position)
	q.exclude = [self]
	q.collision_mask = 1        # 벽(world)만 본다
	var hit := space.intersect_ray(q)
	# 벽에 막히지 않았으면 보인다.
	return hit.is_empty()

extends Node2D

@export var range_px := 900.0
@export var damage := 25

func shoot(dir: Vector2) -> void:
	var space := get_world_2d().direct_space_state
	var from := global_position
	var to := from + dir.normalized() * range_px

	var q := PhysicsRayQueryParameters2D.create(from, to)
	q.exclude = [get_parent()]
	q.collision_mask = 1 | 4     # world + enemy

	var hit := space.intersect_ray(q)
	var end_point: Vector2 = to

	if not hit.is_empty():
		end_point = hit.position
		var body = hit.collider
		if body.has_method("take_damage"):
			body.take_damage(damage)
		_spawn_impact(hit.position, hit.normal)

	_draw_tracer(from, end_point)

func _spawn_impact(pos: Vector2, normal: Vector2) -> void:
	# 벽에 튀는 불꽃. 법선 방향으로 회전시켜 붙인다.
	pass

func _draw_tracer(a: Vector2, b: Vector2) -> void:
	var line := Line2D.new()
	line.add_point(a)
	line.add_point(b)
	line.width = 2.0
	line.default_color = Color(1, 0.9, 0.4, 0.9)
	get_tree().current_scene.add_child(line)
	var tw := line.create_tween()
	tw.tween_property(line, "modulate:a", 0.0, 0.08)
	tw.tween_callback(line.queue_free)

func _draw() -> void:
	if not Engine.is_editor_hint() and OS.is_debug_build():
		var col := Color.RED if _can_see else Color.GRAY
		draw_line(Vector2.ZERO,
			to_local(_target.global_position), col, 1.0)

func _process(_delta: float) -> void:
	queue_redraw()    # _draw를 다시 부르게 한다