7강입력 받기

키를 코드에 박으면 안 되는 이유#

가장 순진한 입력 처리는 이렇습니다.

if Input.is_key_pressed(KEY_D):
	position.x += 300 * delta

동작은 합니다. 그런데 이 코드는 다음을 전부 못 합니다.

• 화살표 키로도 움직이게 하기
• 게임패드 지원
• 모바일 터치 지원
• 사용자가 키 설정 바꾸기
• 왼손잡이용 대체 키

그리고 이런 코드가 프로젝트 전체에 흩어져 있으면, 나중에 게임패드를 붙이려면 모든 파일을 다 뒤져야 합니다.

"move_right"
   ← D키, →키, 패드 스틱 오른쪽, D-Pad 오른쪽

입력 맵 설정하기#

프로젝트 → 프로젝트 설정 → 입력 맵(Input Map) 탭을 엽니다.

1. 위쪽 칸에 move_left 를 입력하고 추가
2. 목록에 생긴 move_left 오른쪽 + 를 눌러 키를 등록
   • 키보드 A
   • 키보드 ←
   • 게임패드 왼쪽 스틱 왼쪽 (Joypad Axis)
3. 같은 방식으로 move_right, move_up, move_down, jump, attack 을 만듭니다

읽는 방법 두 가지#

방법 1 — 폴링 (매 프레임 물어보기)#

"지금 이 키가 눌려 있나?"를 매 프레임 확인합니다. 이동처럼 계속 유지되는 입력에 씁니다.

func _physics_process(delta: float) -> void:
	if Input.is_action_pressed("move_right"):
		position.x += 300.0 * delta

방법 2 — 이벤트 (알림 받기)#

"키가 눌리는 사건이 발생했다"는 알림을 받습니다. 한 번만 반응하는 입력에 좋습니다.

func _unhandled_input(event: InputEvent) -> void:
	if event.is_action_pressed("attack"):
		_shoot()
	elif event.is_action_pressed("ui_cancel"):
		_toggle_pause()

_input()            ← 무조건 가장 먼저. 모든 노드
  ↓
UI(Control) 노드들   ← 버튼 클릭, 텍스트 입력 등
  ↓
_shortcut_input()
  ↓
_unhandled_input()  ← UI가 안 먹은 입력만 여기 온다

4방향 입력을 한 줄로#

상하좌우를 각각 if로 쓰면 길어집니다. Godot에 전용 함수가 있습니다.

var dir := Input.get_vector(
	"move_left", "move_right", "move_up", "move_down")

이 한 줄이 반환하는 것:

• 아무것도 안 누르면 (0, 0)
• 오른쪽만 누르면 (1, 0)
• 오른쪽+아래를 누르면 (0.707, 0.707) ← 이미 정규화되어 있습니다
• 아날로그 스틱이면 기울인 만큼 (0.4, 0.0) 같은 중간값

var dir := Vector2.ZERO
if Input.is_action_pressed("move_right"): dir.x += 1
if Input.is_action_pressed("move_down"):  dir.y += 1
# 오른쪽+아래 = (1, 1) → 길이가 1.414!

실습 — 사방으로 움직이는 캐릭터#

실습용 에셋 내려받기

플레이어 (탑다운) player_top.svg 64×64 내려받기

전부 CC0 다. 에셋 모음 전체 보기 · 한꺼번에 받기 (ZIP)

위 그림은 오른쪽(+X)이 정면입니다. 그래서 look_at() 결과와 그림 방향이 맞습니다.

2강에서 만든 player.tscn의 스크립트를 아래로 교체합니다.

extends Node2D

@export var speed := 300.0

func _physics_process(delta: float) -> void:
	var dir := Input.get_vector(
		"move_left", "move_right", "move_up", "move_down")
	position += dir * speed * delta

세 줄입니다. 이제 WASD·화살표·게임패드 전부로 움직입니다.

실습 — 마우스 방향 보기#

조준을 붙여봅니다.

func _physics_process(delta: float) -> void:
	var dir := Input.get_vector(
		"move_left", "move_right", "move_up", "move_down")
	position += dir * speed * delta

	# 마우스가 있는 쪽을 바라본다.
	look_at(get_global_mouse_position())

look_at() 은 노드의 X축(오른쪽)이 대상을 향하도록 회전시킵니다. 그림이 위쪽을 보고 그려져 있다면 90도 어긋나 보입니다. 그때는 이렇게 보정합니다.

rotation = (get_global_mouse_position()
		- global_position).angle() + PI / 2

# 터치 위치를 조이스틱 방향으로 바꾸는 최소 예
func _input(event: InputEvent) -> void:
	if event is InputEventScreenDrag:
		var v := event.position - _touch_origin
		_stick = v.limit_length(64.0) / 64.0

다음 강의 — 방금 코드를 _physics_process에 넣었습니다. 왜 _process가 아니었을까요? 두 개의 시계를 제대로 봅니다.